CodeAve.com/ASP - Email Checker

CodeAve.com - ASP - Miscellaneous

ASP
·Read/Write
·Script Writers
·Database Display
·Response Objects
·Server Variables
·Random Events
·Articles
·Miscellaneous
·Contents
·What's New?
JavaScript
CSS
HTML
Maps
Links
Mail List
Search
Sitemap

Email Checker

Checking an email address for validity is not an exact science. The best you can hope for is to ensure that the convention (someone@server.ext) is valid. There are third party components that will report back on bad addresses they encounter, but these products can be costly. The following will verify that the user inputted email address follows the typical convention, that all characters entered as part of the address are alphanumeric, that the @ and dot are present and at least separated by one character, and that there are at least two characters after the first dot.

•Text View

•Print View

•Mail this Link

<html>
<title>CodeAve.com(Verify Email Address)</title>
<body bgcolor="#FFFFFF">
<%
' Checks to see if the user inputted a value
' If so, remove leading and trailing blanks and upcase it
u_email= ucase(trim(request.form("u_email")))

' Grab the length of the email address inputted
email_len=len(u_email)

' if the user has inputted a value start checking it
if trim(u_email) <> "" then

' Loop that will check each character of the inputted value
' for the @ and the dot
for counter = 1 to email_len
'If there is an @ set u_at to the position it was found in
if mid(u_email,counter,1)="@" then

' count the number of @'s
at_counter=at_counter+1

' if there is more than one add it to the message
if at_counter > 1 then message = message &"There appear to be multiple @'s in the email address<br>" end if

' if this is the 1st @ note the location in the string
if u_at = "" then
u_at=counter
end if ' end check for first @
end if ' end check for the @

'If there is an dot (.) set u_dot to the position it was found in
if mid(u_email,counter,1)="." then
if u_dot = "" then
u_dot=counter
end if 'end check for the first dot
end if 'end check for the dot

next

' Check to see if the dot comes after the @
' and that the first dot is not the last character
if (u_dot < u_at) or (len(u_email) <= u_dot+1) or ((u_dot-u_at) < 2) then
message = message & "Email convention appears to be wrong <br>"
end if 'end check for dot after the @

' Scan the user input to see that all inputted values are either a letter A-Z,
' a number 0-9 or if the character is a . or and @.
for counter=1 to len(u_email)
if (mid(u_email,counter,1) <> "/") and ((mid(u_email,counter,1) > chr(45)) and (mid(u_email,counter,1) < chr(58))) or ((mid(u_email,counter,1) > chr(63)) and (mid(u_email,counter,1) < chr(91))) then
else
' If it's an invalid charcter add it to the display message
message = message & "Invalid charcter "& mid(u_email,counter,1)& " found in email address <br>"
end if 'end check for invalid characters
next 'end loop for invalid characters
end if 'end check for user input

' If the email address os not OK than display the message(s)
' and show the text box for user input with the last value pre-filled
if message <> "" or u_email = "" then
response.write message %>
<form action="<%= request.servervariables("script_name") %>" method="post">
Enter your email address<br>
<input type="text" name="u_email" value="<%= lcase(u_email) %>">
<input type=submit value=Submit>
<%
' If the email address is ok display it or
' add another process to hereafter
else
response.write lcase(u_email) & " seems ok"
end if %>